O N E   C R A Z Y   M U L T I   T A L E N T Today its Monday, November 29, 2021 @
13:19:45


Type-in fun (C64) - Part #2
in Nostalgia | Sunday, April 15, 2018 | 15:29


Back in the days, I always enjoyed reading magazines and almost everytime a piece of code appeared in the magazines for C64 or Amiga, I couldn't resist typing it in and see what happened!


Here's another batch of Type-Ins I personally find interresting. I have referenced the issue and page number the original type-in was published in, so if you have the magazine available, read on for more details there!

Be sure to check out my first post in these series as well (check bottom link).

I have also created fully runable .PRG out of these, so either copy the code yourselves or simply download the .PRG if you are very lazy.

The sources was typed-in, cleaned and compiled/tested by me using the excellent "CBM prg Studio" suite. As this supports special C64 keys by for instance "{down}" to produce a arrow key down just like on real C64.


AutoRun Creator (again)

This one will create a stand-alone file that auto-run after you had issued a "LOAD" command. Might come in handy someday for my recording projects (SOASC=). It should be noted its dead slow, but really works great :-)

1 rem australian commodore and amiga review
2 rem volume 6, issue 6, page 58
3 rem typed by stone oakvalley march 2018
4 rem ------------------------------------
5 rem *** autorun by shannon rowe ***
10 poke 53280,0 : poke 53281,0 : print chr$(155)chr$(147);
15 open15,8,15
20 print"convert a program to autorun"
25 input "enter name of program ";pr$
30 open1,8,3,pr$+",p,r"
35 input#15,e,e$,e1,e2
40 ifnotethenget#1,a$,b$:ifa$<>chr$(1)thene=1:e$="error"
45 ifethenprinte$:close2:end
50 input"{down}enter new name ";cp$:print"{down}this could take a while"
55 open2,8,4,"0:"+cp$+",p,w"
60 input#15,e,e$,el,e2
65 ifethenprinte$:close2:end
70 forz=0to7:readx:print#2,chr$(x);:nextz
75 for z=1tolen(cp$):print#2,mid$(cp$,z,1);:nextz
80 forz=0to4:readx:print#2,chr$(0);:nextz
85 forz=0to52-len(cp$):print#2,chr$(0);:nextz
100 data 192,2,0,8,1,0,147,34,34,44,56,44,49,139,227,52,3,124,165,26,167,228
105 data 167,134,174,0,0,0,0,76,72,178,0,49,234,102,2,71,254,74,243,145,242,14
110 data 242,80,242,51,243,87,241,202,241,237,246,62,241,47,243,102,254,165,244
115 data 237,245,32,89,166,76,174,167
150 forz=0to57:readx:print#2,chr$(x);:nextz
155 forz=0to1221:print#2,chr$(32);:poke53280,peek(53266):nextz:print#2,chr$(0);
160 get#1,a$:ss=st:iflen(a$)=0thena$=chr$(0)
165 print#2,a$;:poke53280,peek(53266):ifss=0thengoto160
170 close1:close2:close15:poke53280,0
175 input"convert another program ";a$
180 ifa$="y"ora$="yes"thengoto10
185 printchr$(147):new





Kaleidoscope

This one will create a character colorized mirrored 4-corner kaleidoscope - all in pure basic code.

1 rem commodore magazine 
2 rem volume 8, issue 1, page 107
3 rem typed by stone oakvalley april 2018
4 rem ------------------------------------
5 rem *** kaleidoscope by royal c. jones ***
30 print"{clear}";
40 for i=1 to 24:print tab(8)"{reverse on}";
50 for j=1 to 24:print" ";
60 next j:print:next i
70 r=23:rem number of rows -l
80 l=40:rem length of line
90 m=55296+8:rem color memory
100 for i=0 to 11
110 for j=1 to 11
120 c=int(rnd(l)*4)+5
130 poke m+i*l+j,c
140 poke m+j*l+i,c
150 poke m+(r-j)*l+i,c
160 poke m+(r-i)*l+j,c
170 poke m+(r-i)*l+r-j,c
180 poke m+(r-j)*l+r-i,c
190 poke m+j*l+r-i,c
200 poke m+i*l+r-j,c
210 next j,i
220 for i=1 to 3000:next:goto 100


AutoRun Creator (again)




Kaleidoscope




Please review these related article links:
Click to open urlType-in fun (C64) - Part #1
Click to open prgAuto-Run Loader Creator (again)
Click to open prgKaleidoscope


------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
Posted by: Old-schooler, Stone Oakvalley | Publisher: Website Designer, Stone Oakvalley
Last revised: September 21, 2019 - 21:30 | Page views: 596


Website Design by post@stone-oakvalley-studios.com - Copyright © 2021 www.stone-oakvalley-studios.com